v. 1.0.0

Took 1 hour 52 minutes

publish/build.gradle.kts

@@ -0,0 +1,98 @@
+import java.util.*
+
+plugins {
+  `maven-publish`
+  signing
+}
+
+repositories {
+  mavenCentral()
+}
+
+project.extra.set("PUBLISH_GROUP_ID", "nl.astraeus")
+project.extra.set("PUBLISH_VERSION", "1.0.0")
+project.extra.set("PUBLISH_ARTIFACT_ID", "kotlin-css-generator")
+
+apply(from = "${rootProject.projectDir}/build.gradle.kts")
+
+// Stub secrets to let the project sync and build without the publication values set up
+extra["signing.keyId"] = null
+extra["signing.password"] = null
+extra["signing.secretKeyRingFile"] = null
+extra["ossrhUsername"] = null
+extra["ossrhPassword"] = null
+
+// Grabbing secrets from local.properties file or from environment variables, which could be used on CI
+val secretPropsFile = project.rootProject.file("local.properties")
+if (secretPropsFile.exists()) {
+  secretPropsFile.reader().use {
+    Properties().apply {
+      load(it)
+    }
+  }.onEach { (name, value) ->
+    extra[name.toString()] = value
+  }
+} else {
+  extra["signing.keyId"] = System.getenv("SIGNING_KEY_ID")
+  extra["signing.password"] = System.getenv("SIGNING_PASSWORD")
+  extra["signing.secretKeyRingFile"] = System.getenv("SIGNING_SECRET_KEY_RING_FILE")
+  extra["ossrhUsername"] = System.getenv("OSSRH_USERNAME")
+  extra["ossrhPassword"] = System.getenv("OSSRH_PASSWORD")
+}
+
+val javadocJar by tasks.registering(Jar::class) {
+  archiveClassifier.set("javadoc")
+}
+
+fun getExtraString(name: String) = extra[name]?.toString()
+
+publishing {
+  // Configure maven central repository
+  repositories {
+    maven {
+      name = "sonatype"
+      setUrl("https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/")
+      credentials {
+        username = getExtraString("ossrhUsername")
+        password = getExtraString("ossrhPassword")
+      }
+    }
+  }
+
+  // Configure all publications
+  publications.withType<MavenPublication> {
+
+    // Stub javadoc.jar artifact
+    artifact(javadocJar.get())
+
+    // Provide artifacts information requited by Maven Central
+    pom {
+      name.set("kotlin-css-generator")
+      description.set("Kotlin css generator")
+      url.set("https://github.com/rnentjes/kotlin-css-generator")
+
+      licenses {
+        license {
+          name.set("MIT")
+          url.set("https://opensource.org/licenses/MIT")
+        }
+      }
+      developers {
+        developer {
+          id.set("rnentjes")
+          name.set("Rien Nentjes")
+          email.set("info@nentjes.com")
+        }
+      }
+      scm {
+        url.set("https://github.com/rnentjes/kotlin-css-generator")
+      }
+    }
+  }
+}
+
+// Signing artifacts. Signing.* extra properties values will be used
+
+signing {
+  sign(publishing.publications)
+}

publish/publish-mavencentral.gradle

@@ -0,0 +1,121 @@
+
+apply plugin: 'maven-publish'
+apply plugin: 'signing'
+
+task publishSourcesJar(type: Jar) {
+    archiveClassifier.set('sources')
+
+    // For pure Kotlin libraries, in case you have them
+    from sourceSets.main.java.srcDirs
+    //from sourceSets.main.kotlin.srcDirs
+}
+
+task packageJavadoc(type: Jar) {
+    from javadoc
+    classifier = 'javadoc'
+}
+
+artifacts {
+    archives publishSourcesJar
+}
+
+File secretPropsFile = project.rootProject.file('local.properties')
+
+ext["signing.keyId"] = ''
+ext["signing.password"] = ''
+ext["signing.secretKeyRingFile"] = ''
+ext["ossrhUsername"] = ''
+ext["ossrhPassword"] = ''
+ext["sonatypeStagingProfileId"] = ''
+
+if (secretPropsFile.exists()) {
+    Properties p = new Properties()
+
+    new FileInputStream(secretPropsFile).withCloseable { is ->
+        p.load(is)
+    }
+
+    p.each { name, value ->
+        ext[name] = value
+    }
+}
+
+afterEvaluate {
+    publishing {
+        publications {
+            release(MavenPublication) {
+                // The coordinates of the library, being set from variables that
+                // we'll set up later
+                groupId PUBLISH_GROUP_ID
+                artifactId PUBLISH_ARTIFACT_ID
+                version PUBLISH_VERSION
+
+                // Two artifacts, the `aar` (or `jar`) and the sources
+                if (project.plugins.findPlugin("com.android.library")) {
+                    artifact("$buildDir/outputs/aar/${project.getName()}-release.aar")
+                } else {
+                    artifact("$buildDir/libs/${project.getName()}-${version}.jar")
+                }
+                artifact publishSourcesJar
+                artifact packageJavadoc
+
+                // Mostly self-explanatory metadata
+                pom {
+                    name = PUBLISH_ARTIFACT_ID
+                    description = 'Simple JDBC wrapper for query statistics'
+                    url = 'https://github.com/rnentjes/Simple-jdbc-statistics'
+                    licenses {
+                        license {
+                            name = 'MIT License'
+                            url = 'https://github.com/rnentjes/Simple-jdbc-statistics/blob/master/LICENCE.txt'
+                        }
+                    }
+                    developers {
+                        developer {
+                            id = 'rnentjes'
+                            name = 'Rien Nentjes'
+                            email = 'info@nentjes.com'
+                        }
+                        // Add all other devs here...
+                    }
+                    // Version control info - if you're using GitHub, follow the format as seen here
+                    scm {
+                        connection = 'scm:git:github.com/rnentjes/Simple-jdbc-statistics.git'
+                        developerConnection = 'scm:git:ssh://github.com/rnentjes/Simple-jdbc-statistics.git'
+                        url = 'https://github.com/rnentjes/Simple-jdbc-statistics.git/tree/main'
+                    }
+                    // A slightly hacky fix so that your POM will include any transitive dependencies
+                    // that your library builds upon
+                    /*
+                    witXml {
+                        def dependenciesNode = asNode().appendNode('dependencies')
+
+                        project.configurations.implementation.allDependencies.each {
+                            def dependencyNode = dependenciesNode.appendNode('dependency')
+                            dependencyNode.appendNode('groupId', it.group)
+                            dependencyNode.appendNode('artifactId', it.name)
+                            dependencyNode.appendNode('version', it.version)
+                        }
+                    }*/
+                }
+            }
+        }
+        // The repository to publish to, Sonatype/MavenCentral
+        repositories {
+            maven {
+                // This is an arbitrary name, you may also use "mavencentral" or
+                // any other name that's descriptive for you
+                name = "sonatype"
+                url = "https://s01.oss.sonatype.org/service/local/staging/deploy/maven2/"
+                credentials {
+                    username ossrhUsername
+                    password ossrhPassword
+                }
+            }
+        }
+    }
+}
+
+signing {
+    sign publishing.publications
+}

publish/settings.gradle.kts

@@ -0,0 +1,12 @@
+pluginManagement {
+    repositories {
+        mavenCentral()
+
+        maven { setUrl("https://plugins.gradle.org/m2/") }
+    }
+}
+
+rootProject.name = "publish-kotlin-css-generator"
+
+//enableFeaturePreview("GRADLE_METADATA")
+//include(":publish")