import com.vanniktech.maven.publish.SonatypeHost

plugins {
    kotlin("multiplatform") version "2.1.21"
    signing
    id("org.jetbrains.dokka") version "2.0.0"
    id("com.vanniktech.maven.publish") version "0.32.0"
}

group = "nl.astraeus"
version = "0.3.6"

repositories {
    mavenCentral()
    maven {
        url = uri("https://gitea.astraeus.nl/api/packages/rnentjes/maven")
    }
    maven {
        name = "Sonatype Releases"
        url = uri("https://central.sonatype.com/api/v1/publisher/deployments/download/")
    }
}

kotlin {
    //explicitApi()
    jvm()
    js {
        browser()
    }

    sourceSets {
        val commonMain by getting
        val commonTest by getting {
            dependencies {
                implementation(kotlin("test-common"))
            }
        }

        val jvmMain by getting
        val jvmTest by getting {
            dependencies {
                implementation(kotlin("test"))
            }
        }

        val jsMain by getting
        val jsTest by getting {
            dependencies {
                implementation(kotlin("test-js"))
            }
        }
    }
}

publishing {
    repositories {
        mavenLocal()
        maven {
            name = "gitea"
            setUrl("https://gitea.astraeus.nl/api/packages/rnentjes/maven")

            credentials {
                val giteaUsername: String? by project
                val giteaPassword: String? by project

                username = giteaUsername
                password = giteaPassword
            }
        }
        maven {
            name = "gitea8443"
            setUrl("https://gitea.astraeus.nl:8443/api/packages/rnentjes/maven")

            credentials {
                val giteaUsername: String? by project
                val giteaPassword: String? by project

                username = giteaUsername
                password = giteaPassword
            }
        }
    }
}

tasks.withType<AbstractPublishToMaven> {
    dependsOn(tasks.withType<Sign>())
}

signing {
    sign(publishing.publications)
}

mavenPublishing {
    publishToMavenCentral(SonatypeHost.CENTRAL_PORTAL)

    signAllPublications()

    coordinates(group.toString(), name, version.toString())

    pom {
        name = "typed-byte-arrays"
        description = "Typed byte arrays"
        inceptionYear = "2024"
        url = "https://gitea.astraeus.nl/rnentjes/typed-byte-arrays"
        licenses {
            license {
                name = "MIT"
                url = "https://opensource.org/licenses/MIT"
            }
        }
        developers {
            developer {
                id = "rnentjes"
                name = "Rien Nentjes"
                email = "info@nentjes.com"
            }
        }
        scm {
            url = "https://gitea.astraeus.nl/rnentjes/typed-byte-arrays"
        }
    }
}