@file:OptIn(ExperimentalKotlinGradlePluginApi::class)

import org.jetbrains.kotlin.gradle.ExperimentalKotlinGradlePluginApi
import org.jetbrains.kotlin.gradle.dsl.JsSourceMapEmbedMode

buildscript {
    apply(from = "../common.gradle.kts")
}

plugins {
    kotlin("multiplatform")
}

kotlin {
    js {
        compilerOptions {
            target.set("es2015")
            sourceMap.set(true)
            sourceMapEmbedSources.set(JsSourceMapEmbedMode.SOURCE_MAP_SOURCE_CONTENT_ALWAYS)
        }
        browser {
            commonWebpackConfig {
                sourceMaps = true
                devtool = "inline-source-map"
            }
            binaries.executable()
            distribution {
                outputDirectory.set(File("$projectDir/web/"))
            }
        }
    }
    jvm {
    }

    sourceSets {
        val commonMain by getting {
            dependencies {
                implementation(project(":vst-ui-base"))
            }
        }
        val jsMain by getting {
            dependencies {
                api("nl.astraeus:kotlin-komponent:1.2.4")
            }
        }
        val jsTest by getting {
            dependencies {
                implementation(kotlin("test"))
            }
        }
        val jvmMain by getting
    }
}