vst-worklet-base/build.gradle.kts

plugins {
    kotlin("multiplatform") version "2.1.0"
    `maven-publish`
    signing
}

group = "nl.astraeus"
version = "1.0.0"

repositories {
    mavenCentral()
}

kotlin {
    js {
        compilerOptions {
            target.set("es2015")
        }
        binaries.library()
        browser {
        }
    }

    sourceSets {
        val commonMain by getting {
            dependencies {
            }
        }
        val jsMain by getting
        val jsTest by getting {
            dependencies {
                implementation(kotlin("test-js"))
            }
        }
    }
}

extra["PUBLISH_GROUP_ID"] = group
extra["PUBLISH_VERSION"] = version
extra["PUBLISH_ARTIFACT_ID"] = name

// Stub secrets to let the project sync and build without the publication values set up
val signingKeyId: String? by project
val signingPassword: String? by project
val signingSecretKeyRingFile: String? by project

extra["signing.keyId"] = signingKeyId
extra["signing.password"] = signingPassword
extra["signing.secretKeyRingFile"] = signingSecretKeyRingFile

val javadocJar by tasks.registering(Jar::class) {
    archiveClassifier.set("javadoc")
}

publishing {
    repositories {
        maven {
            name = "gitea"
            setUrl("https://gitea.astraeus.nl/api/packages/rnentjes/maven")

            credentials {
                val giteaUsername: String? by project
                val giteaPassword: String? by project

                username = giteaUsername
                password = giteaPassword
            }
        }
        maven {
            name = "gitea8443"
            setUrl("https://gitea.astraeus.nl:8443/api/packages/rnentjes/maven")

            credentials {
                val giteaUsername: String? by project
                val giteaPassword: String? by project

                username = giteaUsername
                password = giteaPassword
            }
        }
    }

    // Configure all publications
    publications.withType<MavenPublication> {
        // Stub javadoc.jar artifact
        artifact(javadocJar.get())

        // Provide artifacts information requited by Maven Central
        pom {
            name.set("vst-worklet-base")
            description.set("Vst worklet base")
            url.set("https://gitea.astraeus.nl/rnentjes/vst-worklet-base")

            licenses {
                license {
                    name.set("MIT")
                    url.set("https://opensource.org/licenses/MIT")
                }
            }
            developers {
                developer {
                    id.set("rnentjes")
                    name.set("Rien Nentjes")
                    email.set("info@nentjes.com")
                }
            }
            scm {
                url.set("https://gitea.astraeus.nl/rnentjes/vst-worklet-base.git")
            }
        }
    }
}

signing {
    sign(publishing.publications)
}

tasks.withType<PublishToMavenRepository> {
    dependsOn(tasks.withType<Sign>())
}